idea自动生成mybtis数据库模型实体类插件

1. 我们在创建一个数据库表的时候,总会为这个表创建一个对应的PO类,里面的字段太多,描述,类型,驼峰转换,重复且劳动量大,IDEA提供了一个插件的入口,使用Groovy语言编写.
2. 它默认提供了一个(不好用),本次脚本可以将数据库表生成mybatis plus标准的实体类,不了解Mybatis plus框架的建议你使用它,它非常好用.
3. 这个脚本存放的位置在左侧项目栏,最下面 临时文件和控制台->扩展->Database Tools and SQL->schema (英文idea自行翻译)
4. 可以看到它默认放了一个 Generate POJOs.groovy ,在这个目录下新建一个文件起名为:Mybatis Plus PO.groovy,将下面的脚本代码复制进去保存
5. 如何使用它呢,先使用idea的工具数据库,连接到你的mysql服务端,然后选中表名(可多选),右击->工具->脚本化扩展程序->Mybatis Plus PO.groovy (英文idea自行翻译) 则可以生成代码了
6. groovy脚本与java写法几乎一样,可以自行调整脚本内容,比如生成文件的作者改为你自己

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.jflove"
typeMapping = [
  (~/(?i)int/)                      : "long",
  (~/(?i)float|double|decimal|real/): "double",
  (~/(?i)datetime|timestamp/)       : "java.sql.Timestamp",
  (~/(?i)date/)                     : "java.sql.Date",
  (~/(?i)time/)                     : "java.sql.Time",
  (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  new File(dir, className + "PO.java").withPrintWriter { out -> generate(out, className, fields,table) }
}

def generate(out, className, fields,table) {
  out.println "package $packageName" + "." + table.getName().substring(0,table.getName().indexOf("_"))+";"
  out.println "import com.baomidou.mybatisplus.annotation.TableId;"
  out.println "import com.baomidou.mybatisplus.annotation.TableName;"
    out.println "import com.baomidou.mybatisplus.annotation.IdType;"
    out.println "import com.baomidou.mybatisplus.annotation.FieldFill;"
    out.println "import com.baomidou.mybatisplus.annotation.TableField;"
    out.println "import lombok.Getter;"
    out.println "import lombok.Setter;"
    out.println "import lombok.ToString;"
    out.println "import java.io.Serializable;"
    out.println "import java.io.Serial;"
    out.println ""
    out.println ""
    out.println "/**"
    out.println " * @author tanjun"
    out.println " * @date " + new java.util.Date().toString()
    out.println " * @describe ${table.getComment()}"
    out.println " */"
    out.println "@Getter"
    out.println "@Setter"
    out.println "@ToString"
    out.println "@TableName(\"${table.getName()}\")"
  out.println "public class ${className}PO implements Serializable{"
  out.println "\t@Serial"
    out.println genSerialID()
    out.println ""
  fields.each() {
    if (it.annos != "") out.println "  ${it.annos}"
      out.println "  /**"
      out.println "   * ${it.commoent}"
      out.println "   */"
      if(it.isPk){
          out.println "  @TableId(type = IdType.AUTO)"
      }
      if("createTime".equalsIgnoreCase(it.name)){
          out.println "  @TableField(fill = FieldFill.INSERT)"
      }
      if("updateTime".equalsIgnoreCase(it.name)){
          out.println "  @TableField(fill = FieldFill.INSERT_UPDATE)"
      }
      out.println "  private ${it.type} ${it.name};"
  }
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                 name : javaName(col.getName(), false),
                 type : typeStr,
                 commoent : col.getComment(),
                 isPk : "id".equalsIgnoreCase(col.getName()),
                 annos: ""]]
  }
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
    .collect { Case.LOWER.apply(it).capitalize() }
    .join("")
    .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
static String genSerialID() {
 return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;";
}